[SAS] PROC TABULATE

1. TABULATE 프로시저의 기본 형식 

TABULATE 프로시저는 테이블을 작성할 때 사용하며, FREQ 프로시저보다 다양한 형식의 통계 테이블을 작성할 수 있습니다.

 

[기본 형식]

PROC TABULATE <OPTION> <STYLE> 형식;
	<BY 변수명>
    TABLE 행변수명<OPTION>, 열변수명<OPTION>;
    CLASS 변수명;
    VAR 변수명;
    [FORMAT 변수명 형식이름];
RUN;

**TABULATE 프로시저 명령들

1) Class    2) Var    3) Table    4) Format 

 

Table 명령에서 작성하고자 하는 표의 행, 열 변수를 지정하며 기본적인 규칙은 아래와 같습니다.

- Table 명령에서 적어도 1개 이상의 변수를 지정

- Table 명령에 사용되는 차원변수는 Class / Var에서 지정. (범주형인 경우 Class명령에서, 통계값이 산출되는 분석 변수는 Var에서 지정.)

- 분석 변수는 동일 차원에서 정의해야 하며, 교차될 수 없다. 즉, 각 차원에서 1개의 분석 변수만 정의할 수 있다.

 

 

 

2. 테이블 차원

1) 1차원 테이블 : TABLE 1행*1열변수

TABLE AgeAtDeath AgeAtDeath*MEAN은 각각 AgeAtDeath의 합계와 평균을 산출합니다.

/* 1. AgeAtDeath 합과 평균을 계산한 TABLE 출력 */
PROC TABULATE DATA=heart;
  TABLE AgeAtDeath AgeAtDeath*MEAN ; 	/* SCORE의 합계, 평균 출력 */
  VAR AgeAtDeath;
RUN;

 

2) 2차원 테이블 : TABLE 행변수,열변수

/* Status 레벨에 따른 Smoking의 평균*/
PROC TABULATE DATA=heart;
	CLASS Status;
    VAR Smoking;
    TABLE Smoking*MEAN,Status; 	
    TABLE Status,Smoking*MEAN; 	/* 행렬전환 */
RUN;

TABLE Smoking*MEAN,Status;

TABLE Status,Smoking*MEAN

 

 

3) 다차원 테이블 : TABLE 페이지 변수, 행변수,열변수

PROC TABULATE DATA=heart;
	CLASS Status Sex;
    VAR Smoking;
	/* STATUS을 행으로, SEX를 열로 한 SMOKING의 평균값*/
    TABLE Status,Sex*Smoking*MEAN;  
	/* SEX를 행으로, STATUS을 열로 한 SMOKING 횟수의 평균값*/
    TABLE Sex*Smoking*MEAN,Status;
RUN;

TABLE Status,Sex*Smoking*MEAN

TABLE Sex*Smoking*MEAN,Status;

 

PROC TABULATE DATA=heart;
	CLASS Status Sex;
    VAR Smoking;
    TABLE Status*Sex*Smoking*MEAN;  
RUN;

** 출력값 옵션

TABLE 변수*(통계값1 통계값2 ..)와 같은 형식으로 원하는 통계치를 산출할 수 있습니다.

PROC TABULATE DATA=heart;
	CLASS Status;
    VAR Smoking ;
    TABLE Status,Smoking*(N MEAN SUM MEDIAN MAX MIN STDDEV VAR);
    /* 관측수, 평균, 합계, 중앙값, 최대값, 최소값, 표준편차, 분산  */
RUN;

 

 

3. 테이블 스타일

/* 테이블 스타일 */
PROC TABULATE DATA=heart STYLE=[FONTSIZE=5];
	CLASS Status / STYLE=[FONTSIZE=3];
    VAR Smoking /STYLE=[FONTWIDTH=WIDE];
    TABLE Status*Smoking*(N MEAN);
RUN;